Sergio Gago

Si sabes qué es esto, molas.

1 REM THERE'S GOLD IN THEM THERE SKYSCRAPERS FROM
2 REM 34 MORE TESTED, READY TO RUN GAME PROGRAMS IN BASIC
3 DIM A(500)
4 REM SOME MODIFICATIONS WERE NEEDED FOR MBASIC, DONE BY PETER DASSOW
5 GOSUB 700:PRINT:FOR X=1 TO 100: LET A(X)=0:NEXT X
10 PRINT "GOLD IN THEM THERE SKYSCRAPERS"
15 INPUT "ENTER 1 FOR INSTRUCTIONS OR 2 FOR GAME ";X
20 IF X=1 THEN GOTO 450
25 REM ** PUT DOORS IN ALL ROOMS
30 FOR X=101 TO 500:LET A(X)=1:NEXT X
35 REM ** REMOVE IMPOSSIBLE DOORS
40 FOR X=391 TO 410: LET A(X)=0:NEXT X
45 LET Y=201:FOR X= 1 TO 10
50 LET A(Y)=0:LET Y=Y+10:NEXT X
60 LET Y=110:FOR X=1 TO 10
65 LET A(Y)=0:LET Y=Y+10:NEXT X
70 REM ** REMOVE RANDOM DOORS
75 LET Y=INT(RND(1)*5)+1
80 FOR X=1 TO Y:LET Z=INT(RND(1)*400)+101
90 LET A(Z)=0:NEXT X
100 REM ** PLANT TRAP DOORS
105 LET Y=INT(RND(1)*20)+1
110 FOR X=1 TO Y:LET Z=INT(RND(1)*90)+11
120 LET A(Z)=4:NEXT X
122 LET Y=INT(RND(1)*40)+1:FOR X=1 TO Y
123 LET Z=INT(RND(1)*100)+1
124 LET A(Z)=5:NEXT X:LET S=5
125 REM ** PLANT EXITS & GOLD
130 FOR X=1 TO 3: LET Y=INT(RND(1)*10)+1
135 LET A(Y)=3:NEXT X:LET A(1)=1
140 LET X=INT(RND(1)*99)+2:LET A(X)=2
150 REM ** SET GAME VARIABLES
155 LET M=1: LET P=1:LET G=0
160 LET E=3:LET U=10:LET D=-10
170 LET R=1:LET L=-1
180 LET H=X:REM REMEMBER THE GOLD ROOM
200 PRINT "MOVE #";M:LET M=M+1
205 PRINT "YOU ARE IN ROOM #";P
210 LET X=A(P)
215 IF X=2 THEN GOSUB 400
220 IF X=3 THEN PRINT "THERE IS AN EXIT."
225 IF X=4 THEN GOTO 420
227 IF X=5 THEN PRINT "THERE IS A SECRET PASSAGEWAY (COMMAND 'SECRET') "
230 PRINT "YOU CAN MOVE IN THE FOLLOWING DIRECTIONS --- ";
235 LET Y=P+100:IF A(Y)=1 THEN PRINT "RIGHT ";
240 LET Y=P+200:IF A(Y)=1 THEN PRINT "LEFT ";
245 LET Y=P+300:IF A(Y)=1 THEN PRINT "UP ";
250 LET Y=P+400:IF A(Y)=1 THEN PRINT "DOWN ";
255 PRINT: PRINT
260 INPUT "YOUR MOVE ";Q$
262 LET Q$=LEFT$(Q$,1)
265 IF Q$="E" OR Q$="e" THEN GOTO 300
270 IF Q$="R" OR Q$="r" THEN DIFF=R:GOTO 340
275 IF Q$="L" OR Q$="l" THEN DIFF=L:GOTO 370
280 IF Q$="U" OR Q$="u" THEN DIFF=U:GOTO 380
285 IF Q$="D" OR Q$="d" THEN DIFF=D:GOTO 390
287 IF Q$="S" OR Q$="s" THEN GOTO 600
288 IF Q$="?" THEN PRINT "TRY ROOM ";H:PRINT:GOTO 260
290 PRINT "INVALID MOVE!"
295 GOTO 200
300 IF A(P)=E THEN GOTO 310
305 GOTO 290
310 PRINT "YOU HAVE JUST LEFT THE BUILDING WITH";
315 IF G=0 THEN PRINT "OUT";
320 PRINT " THE GOLD."
325 LET M=M-1
330 PRINT "IT TOOK YOU ";M;" MOVES."
335 END
340 REM ** MOVE = RIGHT
345 LET X=P+100
350 IF A(X)=1 THEN GOTO 365
355 PRINT "YOU JUST RAN INTO A WALL, CLOD!"
360 GOTO 200
365 LET P=P+DIFF:GOTO 200
370 REM ** MOVE = LEFT
375 LET X=P+200: GOTO 350
380 REM ** MOVE = UP
385 LET X=P+300: GOTO 350
390 REM ** MOVE = DOWN
395 LET X=P+400:GOTO 350
400 PRINT "YOU JUST FOUND THE GOLD!"
405 LET A(P)=0: LET G=L
410 RETURN
420 PRINT "TRAP DOOR!"
425 LET P=P-10
430 FOR X=1 TO 333:NEXT X: REM DELAY
440 GOTO 200
450 PRINT "YOU JUST HAVE TO FIND YOUR WAY WITHIN THAT BIG BUILDING."
460 PRINT "TRY TO FIND THE ROOM WITH THE GOLD, THEN EXIT"
470 PRINT "THE BUILDING. TRY TO USE A MINIMAL NUMBER OF STEPS."
480 GOTO 15
590 REM ** Secret Passageway Option
600 IF A(P)=5 THEN GOTO 620
610 GOTO 290
620 GOSUB 700:LET P=INT(RND(1)*100)+1
630 FOR X=1 TO 456: NEXT X
640 GOTO 200
700 FOR LINES=1 TO 24:PRINT:NEXT LINES
710 RETURN
SUB 700:LET